package events 
{
	import flash.events.Event;
	
	/**
	 * ...
	 * @author Kasoi
	 */
	public class VKWrapperEvent extends Event 
	{
		
		/// Пользователь добавляет приложение к себе на страницу. 
		static public const ON_APPLICATION_ADDED: String = 'onApplicationAdded';
		
		/*
		 * @settings: Number
		 * Пользователь изменяет настройки приложений. Параметр settings содержит в себе
		 * битовую маску выставленных значений настроек. 0 – настройки не выставлены.
		 * +1 – разрешены уведомления, +2 – разрешен доступ к друзьям, +4 – разрешен доступ 
		 * к фотографиям, +8 – разрешен доступ к аудиозаписям, +32 – разрешен доступ к 
		 * предложениям, +64 – разрешен доступ к вопросам.
		 */
		static public const ON_SETTINGS_CHANGED: String = 'onSettingsChanged';
		
		/*
		 * @balance: Number
		 * Пользователь положил или снял голоса с баланса приложения. Параметр balance 
		 * содержит текущий баланс пользователя в сотых долях голоса. Этот параметр можно 
		 * использовать только для вывода пользователю. Достоверность баланса всегда нужно 
		 * проверять с помощью метода secure.getBalance. 
		 */
		static public const ON_BALANCE_CHANGED: String = 'onBalanceChanged';
		
		/*
		 * Событие происходит, когда пользователь подтвердил сохранение фотографии в окне, 
		 * вызванном с помощью функции showProfilePhotoBox.
		 */
		static public const ON_PROFILE_PHOTO_SAVE: String = 'onProfilePhotoSave';
		
		/*
		 * @width: Number, @height: Number
		 * Размер окна приложения был изменен. Параметры width и height
		 * содержат новые размеры приложения в пикселах.
		 */
		static public const ON_WINDOW_RESIZED: String = 'onWindowResized';
		
		/*
		 * @location: String
		 * Изменяется значение хеша после символа # в адресной строке браузера. Например, 
		 * это происходит в результате использования кнопок "назад" и "вперед"
		 * в браузере. Данное событие происходит всегда при запуске приложения.
		 */
		static public const ON_LOCATION_CHANGED: String = 'onLocationChanged';
		
		/*
		 * Окно с приложением теряет фокус. Например, когда пользователь открывает окно 
		 * с настройками приложения.
		 */
		static public const ON_WINDOW_BLUR: String = 'onWindowBlur';
		
		/*
		 * 	Окно с приложением получает фокус. Например, когда пользователь 
		 * закрывает окно с настройками приложения. 
		 */
		static public const ON_WINDOW_FOCUS: String = 'onWindowFocus';
		
		/*
		 * Пользователь переносит указатель мыши за пределы окна приложения. Это 
		 * событие является аналогом Event.MOUSE_LEAVE объекта stage.
		 */
		static public const ON_MOUSE_LEAVE: String = 'onMouseLeave';
		
		
		public var settings: Number;
		
		public var balance: Number;
		
		public var width: Number;
		
		public var height: Number;
		
		public var location: String;
		
		public function VKWrapperEvent(type: String, settings: Number = NaN, balance: Number = NaN,
			width: Number = NaN, height: Number = NaN, location: String = null, 
			bubbles:Boolean = false, cancelable:Boolean = false) 
		{ 
			this.settings = settings;
			this.balance = balance;
			this.width = width;
			this.height = height;
			this.location = location;
			super(type, bubbles, cancelable);
		} 
		
		public override function clone(): Event 
		{ 
			return new VKWrapperEvent(type, this.settings, this.balance, this.width, 
				this.height, this.location, bubbles, cancelable);
		} 
		
		public override function toString():String 
		{ 
			return formatToString("VKWrapperEvent", "type", "settings", "balance", "width", 
				"height", "location", "bubbles", "cancelable", "eventPhase"); 
		}
		
	}
	
}